If - DOS/コマンドプロンプト コマンド一覧

オプション一覧

errorlevel

errorlevel による終了コードの評価(比較)は、説明にあるように、指定した数値以上の値であればヒットとなるため、複数の終了コードをチェックしたい場合は、数値の大きい順に終了コードをチェックしていく必要があります。例えば、

if errorlevel 1 goto label1
if errorlevel 2 goto label2
if errorlevel 3 goto label3
if errorlevel 4 goto label4
.
.
.

のコードでは、終了コードが 0 でなかった場合(1 以上の場合)は、1 だろうと 4 だろうとラベル「label1」にジャンプしてしまいます。よって正しくは

if errorlevel 4 goto label4
if errorlevel 3 goto label3
if errorlevel 2 goto label2
if errorlevel 1 goto label1
.
.
.

とします。なお、一般的なプログラムは正常終了した場合に終了コードを0に設定するため(Choiceなどの例外もあります)、「if errorlevel 1 goto OnError」と記述すればほとんどの場合でプログラムにエラーが発生したときの処理を分岐させることができます。

[Windows NT系] errorlevelの確認に負の値(マイナスの値)を用いることもできます。

[Windows NT系] [拡張機能] 拡張機能が有効になっている場合、この構文の代わりに下記の文字列比較構文を用い、「ERRORLEVEL」環境変数を使用して値の比較を行うことができます。例えば以下のように書くことができます。

rem 終了コードが2のときジャンプ
if "%ERRORLEVEL%"=="2" goto label2
rem 終了コードが1以下のときジャンプ
if "%ERRORLEVEL%" LEQ "1" goto label0_1
.
.
.

exist

exist はファイルが存在するかどうかをチェックします。ファイルは隠しファイルやシステムファイルであっても、このコマンドで存在を確認することが出来てしまいます。

ディレクトリの存在が確かめられるかどうかは、Windows 95 と XP では挙動が異なるため、注意が必要です。(実際にテストするには、例えばプロンプト上で「if exist C:\WINDOWS echo ok」などと入力して「ok」と表示されれば、ディレクトリに対しても使用できることを表します。)

なお、NULファイルを用いることで、MS-DOS・Windows 9x・Windows NT系すべてでディレクトリの存在確認(およびファイルではなくディレクトリかどうかの確認)を行うことができます。

if exist X:\Hoge\NUL echo ok

このコマンドを実行すると、「X:\Hoge」がディレクトリとして存在する場合に「ok」が画面に出力されます。(X:\Hoge が存在しない、あるいはディレクトリではない場合には「echo ok」が実行されません。)

文字列比較

文字列比較は、環境変数の値やバッチファイルに指定された引数を評価(比較)するのによく使います。環境変数や引数の値は「%」を使って取得できる(環境変数TEMPなら「%TEMP%」、「2番目の引数」なら「%2」← Shift コマンドも参照)ので、上記の <string1> や <string2> にそれらを指定します。

上記にあるように、クオーテーションマークは必要ありません。以下のコードもご覧ください。

if "test"=="test" echo 1
if "test==test" echo 2
if test"==test" echo 3
if !test==!test echo 4
if !%1==!hello echo 5

このコードで出力される数値は 1, 3, 4 です。また、バッチファイルの引数に「hello」が指定されている場合(%1 が hello である場合)は、数値 5 も出力されます。

ただし、環境変数の値を比較する場合、その環境変数が空である場合を考慮するとクオーテーションマーク(またはその他文字や記号)が必要になる場合があります。これは、比較対象の文字列に何も指定されていない場合は構文エラーとなるためです。例えば、

if %foo%==foo echo ok

と書いた場合、環境変数「foo」が空であると構文エラーとみなされます。これを防止するには、

rem -- 以下のいずれでも可
if "%foo%"=="foo" echo ok
if $%foo%==$foo echo ok

のような書き方をする必要があります。

※ 同様に、文字列が空であるかどうかをチェックする場合もクオーテーションマークなどが必要になります。

任意の比較

[Windows NT 系] [拡張機能] 「LSS」や「GEQ」など、「==」以外の演算子を用いて文字列または数値の比較を行い、それによって後続の処理を変えることができます(演算子は「構文」参照)。比較対象がともに数値になっている場合は数値として比較を行いますが、一方が数値ではない文字列の場合はアルファベットが辞書式順序に従って大きいか小さいかの比較が行われます。ただし「/I」が指定されていない場合、まずは大文字・小文字を区別しない比較が行われ、そこで一致する場合に「小文字の方が大文字より小さい」として比較を行います。

※ アルファベットと数字以外の文字についてはどの順序で比較されるか不明です。

rem -- 文字列が一致する場合
if "aaa" EQU "aaa" echo 1
rem -- 大文字・小文字のみ一致しない場合
if "aaa" EQU "Aaa" echo 2
rem -- 「/I」があり、大文字・小文字のみ一致しない場合
if /i "aaa" EQU "Aaa" echo 3
rem -- 「より小さい」比較で文字列が一致する場合
if "aaa" LSS "aaa" echo 4
rem -- 「より小さい」比較で文字列が一致しない場合(「a」＜「b」)
if "aba" LSS "aaa" echo 5
rem -- 「より小さい」比較で文字列が一致しない場合、辞書式順序の適用(「ab」＜「ba」)
if "aba" LSS "baa" echo 6
rem -- 「より小さい」比較で文字列が一致しない場合(「b」＜「c」)
if "aab" LSS "aac" echo 7
rem -- 「より小さい」比較で文字列が大文字・小文字のみ一致しない場合(「a」＜「A」)
if "aaa" LSS "Aaa" echo 8
rem -- 「より小さい」比較で大文字・小文字よりも文字違いを優先する場合1(「A」＜「b」)
if "baa" LSS "Aaa" echo 9
rem -- 「より小さい」比較で大文字・小文字よりも文字違いを優先する場合2(「Aa」＜「ab」)
if "aba" LSS "Aaa" echo 10
rem -- 「数値」として扱うことができるのは整数のみ(小数は認識されない)
if "1" EQU "1.0" echo 11

この例では「1」「3」「6」「7」「8」が出力されます。

else

[Windows NT 系] 条件に当てはまる場合と当てはまらない場合それぞれでコマンドを実行したい場合に使用します。「else」は「if」を書いた行と同じ行に書く必要がありますが、コマンドラインは「コマンドの末尾を改行またはブロックの終端にする」必要があるため、以下のように「( )」を用いて記述する必要があります。

if /i "%~1"=="/delete" (del mydata.dat) else (echo Not deleted.)

(括弧「( )」を用いないと「"%~1"=="/delete"」以降が「del mydata.dat else echo Not deleted.」というコマンドラインに解釈されてしまいます。)

その他

[Windows NT 系] 条件に当てはまる際に実行するコマンドを1つではなく複数実行したい場合は、それらのコマンドを「( )」で囲んで複数行に分けて記述します。例えば、

if "test"=="test" (
    echo 1
    echo 2
)

を実行すると、2行にわたって「1」と「2」が出力されます。なお、環境変数の展開はIfの処理が行われる際に括弧内も含めてすべて行われるため、括弧内でSetを用いている場合は注意が必要です(Setlocalおよび「!」の説明も参照)。

else を用いる場合は、最初の閉じ括弧の直後に else を記述します。閉じ括弧の後に改行を入れることはできません(「( )」全体がひとまとまりの(改行されていない) <command-line> になるため)。

if "test"=="test" (
    echo 1
    echo 2
) else (
    echo 3
    echo 4
)